The Driver-Pressure-Statement-Impact-Response (DPSIR) framework was defined by the European Environmental Agency (EEA) in 1999 to describe interactions between society and the environment [1]. The framework consists of five components: driver, pressure, state, impact, and response. Together, these form a cause-and-effect chain. When annotating the IPCC report, this framework can be used to create a more structured set of annotations.
In the DPSIR framework, drivers are human activities — such as farming, travelling, and fishing — that affect the environment. In this Wikibase, natural processes that affect the environment are also included as drivers. The Wikibase has the following drivers:
SPARQL sparql/drivers.rq (run, edit)
PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd: <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
PREFIX p: <https://kg-ipclimatec-reports.wikibase.cloud/prop/>
PREFIX pq: <https://kg-ipclimatec-reports.wikibase.cloud/prop/qualifier/>
SELECT ?driver ?driverLabel (COUNT(DISTINCT ?statement) AS ?count) WHERE {
?paragraph p:P3 ?statement .
?statement pq:P18 ?driver .
?driver wdt:P1/wdt:P6* wd:Q276 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?driver ?driverLabel
ORDER BY DESC(?count)
This gives:
| driver | count |
| human activities | 6 |
| volcanic | 1 |
| solar | 1 |
The way that drivers affect the environment is expressed in pressures. For example, one pressure that results from travel is the emission of greenhouse gases from combustion engines. The Wikibase has the following pressures:
SPARQL sparql/pressures.rq (run, edit)
PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd: <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
PREFIX p: <https://kg-ipclimatec-reports.wikibase.cloud/prop/>
PREFIX pq: <https://kg-ipclimatec-reports.wikibase.cloud/prop/qualifier/>
SELECT ?pressure ?pressureLabel (COUNT(DISTINCT ?statement) AS ?count) WHERE {
?paragraph p:P3 ?statement .
?statement pq:P19 ?pressure .
?pressure wdt:P1/wdt:P6* wd:Q285 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?pressure ?pressureLabel
ORDER BY DESC(?count)
This gives:
| pressure | count |
| greenhouse gas emission | 8 |
| CO₂ emission | 4 |
| aerosol emissions | 2 |
| methane emission | 1 |
The properties of the environment that pressures change are called states. For example, the emission of CO₂ results in the changing of the state “atmospheric CO₂ concentration”, and indirectly the state “surface temperature”. The Wikibase has the following pressures:
SPARQL sparql/states.rq (run, edit)
PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd: <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
PREFIX p: <https://kg-ipclimatec-reports.wikibase.cloud/prop/>
PREFIX pq: <https://kg-ipclimatec-reports.wikibase.cloud/prop/qualifier/>
SELECT ?state ?stateLabel (COUNT(DISTINCT ?statement) AS ?count) WHERE {
?paragraph p:P3 ?statement .
?statement pq:P20 ?state .
?state wdt:P1/wdt:P6* wd:Q286 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?state ?stateLabel
ORDER BY DESC(?count)
This gives:
| state | count |
| global surface temperature | 2 |
| concentrations of well-mixed GHG | 1 |
Changes in the state of different properties of the environment can then have impacts on human life and other aspects of the environment that we give intrinsic value. The Wikibase has the following impacts:
SPARQL sparql/impacts.rq (run, edit)
PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd: <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
PREFIX p: <https://kg-ipclimatec-reports.wikibase.cloud/prop/>
PREFIX pq: <https://kg-ipclimatec-reports.wikibase.cloud/prop/qualifier/>
SELECT ?impact ?impactLabel (COUNT(DISTINCT ?statement) AS ?count) WHERE {
?paragraph p:P3 ?statement .
?statement pq:P10 ?impact .
?impact wdt:P1/wdt:P6* wd:Q41 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?impact ?impactLabel
ORDER BY DESC(?count)
This gives:
| impact | count |
| reduced food security | 1 |
| affected water security | 1 |
Finally, these impacts can trigger society and policy-makers to respond, either by mitigating the impact, counter-acting the change in state, eliminating the pressure, or fundamentally changing human activity. The Wikibase has the following responses:
SPARQL sparql/responses.rq (run, edit)
PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd: <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
PREFIX p: <https://kg-ipclimatec-reports.wikibase.cloud/prop/>
PREFIX pq: <https://kg-ipclimatec-reports.wikibase.cloud/prop/qualifier/>
SELECT ?response ?responseLabel (COUNT(DISTINCT ?statement) AS ?count) WHERE {
?paragraph p:P3 ?statement .
?statement pq:P21 ?response .
?response wdt:P1/wdt:P6* wd:Q288 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?response ?responseLabel
ORDER BY DESC(?count)
This gives:
Together, these components form a chain of cause and effect. Within a statement in the IPCC report, such cause-and-effect relationships are mentioned. By annotating these statements with their different DPSIR components, the chain can be derived:
SPARQL sparql/dpsir.rq (run, edit)
PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd: <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
PREFIX p: <https://kg-ipclimatec-reports.wikibase.cloud/prop/>
PREFIX pq: <https://kg-ipclimatec-reports.wikibase.cloud/prop/qualifier/>
SELECT DISTINCT ?driver ?driverLabel ?pressure ?pressureLabel ?state ?stateLabel ?impact ?impactLabel ?response ?responseLabel WITH {
SELECT DISTINCT ?driver ?pressure ?state ?impact ?response WHERE {
?fact ^p:P3 / wdt:P1 wd:Q18 .
OPTIONAL { ?fact pq:P18 ?driver ; pq:P19 ?pressure }
OPTIONAL { ?fact pq:P19 ?pressure ; pq:P20 ?state }
OPTIONAL { ?fact pq:P20 ?state ; pq:P10 ?impact }
OPTIONAL { ?fact pq:P10 ?impact ; pq:P21 ?response }
}
} AS %PARAGRAPHS WHERE {
INCLUDE %PARAGRAPHS
BIND (COALESCE(?driver, ?pressure, ?state, ?impact, ?response) AS ?someDPSIR)
FILTER (BOUND(?someDPSIR))
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
This gives: