IPCC-Queries

Sections, Paragraphs and Statements

The AR6 Syntheses Report consists of many sections, each of which has one or more paragraphs [1]. Each paragraph, in turn, contains one or more facts.

Sections

We can list all the sections in the book:

SPARQL sparql/allSections.rq (run, edit)

PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd:  <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
SELECT ?section ?sectionLabel WHERE {
  ?section wdt:P1 wd:Q18 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} ORDER BY ASC(?sectionLabel)

Which gives:

section
2.1.1 Observed Warming and its Causes
2.1.1.a
2.1.1.b
This table is truncated. See the full table at sparql/allSections.rq

Instead, we can also focus on paragraphs (also typed as section):

SPARQL sparql/sectionsWithStatements.rq (run, edit)

PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd:  <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
SELECT DISTINCT ?section ?sectionLabel (COUNT(?statement) AS ?count) WHERE {
  ?section wdt:P1 wd:Q18 ;
           wdt:P3 ?statement .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?section ?sectionLabel
  ORDER BY DESC(?count)

Which gives:

section	count
2.1.2.c	11
2.1.2.l	10
3.1.3.b	9
2.1.2.d	7
4.9.c	6
2.1.1.h	5
3.1.1.h	5
2.1.1.b	4
2.3.2.b	4
3.1.1.f	4
2.1.2.a	3
2.1.1.a	2
4.9.d	2
2.1.1.g	1
2.1.1.i	1
4.1.f	1
2.1.1.e	1

Paragraphs

For each section we can list the paragraphs and their confidence levels, for example for paragraph paragraph 2.1.2.d (Q49):

SPARQL sparql/statementsWithConfidence.rq (run, edit)

PREFIX wdt: <https://kg-ipclimatec-reports.wikibase.cloud/prop/direct/>
PREFIX wd:  <https://kg-ipclimatec-reports.wikibase.cloud/entity/>
PREFIX p:   <https://kg-ipclimatec-reports.wikibase.cloud/prop/>
PREFIX pq:  <https://kg-ipclimatec-reports.wikibase.cloud/prop/qualifier/>
PREFIX ps:  <https://kg-ipclimatec-reports.wikibase.cloud/prop/statement/>
SELECT DISTINCT ?fact ?factLabel (GROUP_CONCAT(?value_string; separator=", ") as ?confidences) WHERE {
  VALUES ?section { wd:Q49 }
  ?section p:P3 ?factStatement .
  BIND (?section AS ?fact)
  ?factStatement ps:P3 ?factLabel .
  ?factStatement pq:P5 ?confidence .
  ?confidence rdfs:label ?value_string . 
  FILTER (LANG(?value_string) = 'en')
} GROUP BY ?fact ?factLabel

Which gives for this paragraph:

fact	confidences
Although overall agricultural productivity has increased, climate change has slowed this growth in agricultural productivity over the past 50 years globally (medium confidence), with related negative crop yield impacts mainly recorded in mid- and low latitude regions, and some positive impacts in some high latitude regions (high confidence).	high confidence, medium confidence
Climate change has reduced food security and affected water security due to warming, changing precipitation patterns, reduction and loss of cryospheric elements, and greater frequency and intensity of climatic extremes, thereby hindering efforts to meet Sustainable Development Goals (high confidence).	high confidence
Ocean warming in the 20th century and beyond has contributed to an overall decrease in maximum catch potential (medium confidence), compounding the impacts from overfishing for some fish stocks (high confidence).	high confidence, medium confidence
Ocean warming and ocean acidification have adversely affected food production from shellfish aquaculture and fisheries in some oceanic regions (high confidence).	high confidence
Roughly half of the world’s population currently experiences severe water scarcity for at least some part of the year due to a combination of climatic and non-climatic drivers (medium confidence) (Figure 2.3).	medium confidence
Unsustainable agricultural expansion, driven in part by unbalanced diets, increases ecosystem and human vulnerability and leads to competition for land and/or water resources (high confidence).	high confidence
Increasing weather and climate extreme events have exposed millions of people to acute food insecurity and reduced water security, with the largest impacts observed in many locations and/or communities in Africa, Asia, Central and South America, LDCs, Small Islands and the Arctic, and for small-scale food producers, low-income households and Indigenous Peoples globally (high confidence).	high confidence

References

AR6 Synthesis Report: Climate Change 2023 [Internet]. Sixth Assessment Report. Geneva, Confoederatio Helvetica: Intergovernmental Panel on Climate Change; Available from: https://www.ipcc.ch/report/ar6/syr/

This site is open source. Improve this page.